let X be non empty set ; :: thesis: ex Y being set st
( Y in X & ( for Y1, Y2, Y3 being set st Y1 in Y2 & Y2 in Y3 & Y3 in Y holds
Y1 misses X ) )
defpred S1[ set ] means ex Y1, Y2 being set st
( Y1 in Y2 & Y2 in $1 & Y1 meets X );
consider Z1 being set such that
A1: for Y being set holds
( Y in Z1 iff ( Y in union X & S1[Y] ) ) from XFAMILY:sch 1();
 defpred S2[ set ] means $1 meets X;
defpred S3[ set ] means ex Y1 being set st
( Y1 in $1 & Y1 meets X );
consider Z2 being set such that
A2: for Y being set holds
( Y in Z2 iff ( Y in union (union X) & S3[Y] ) ) from XFAMILY:sch 1();
 consider Z3 being set such that
A3: for Y being set holds
( Y in Z3 iff ( Y in union (union (union X)) & S2[Y] ) ) from XFAMILY:sch 1();
 consider Y being set such that
A4: Y in ((X \/ Z1) \/ Z2) \/ Z3 and
A5: Y misses ((X \/ Z1) \/ Z2) \/ Z3 by Th1;
A6: now :: thesis: not Y in Z2
assume A7: Y in Z2 ; :: thesis: contradiction
then consider Y1 being set such that
A8: Y1 in Y and
A9: Y1 meets X by A2;
Y in union (union X) by A2, A7;
then Y1 in union (union (union X)) by A8, TARSKI:def 4;
then Y1 in Z3 by A3, A9;
then Y1 in ((X \/ Z1) \/ Z2) \/ Z3 by XBOOLE_0:def 3;
hence contradiction by A5, A8, XBOOLE_0:3; :: thesis: verum
end;
A10: now :: thesis: not Y in Z1
assume A11: Y in Z1 ; :: thesis: contradiction
then consider Y1, Y2 being set such that
A12: Y1 in Y2 and
A13: Y2 in Y and
A14: Y1 meets X by A1;
Y in union X by A1, A11;
then Y2 in union (union X) by A13, TARSKI:def 4;
then Y2 in Z2 by A2, A12, A14;
then Y2 in (X \/ Z1) \/ Z2 by XBOOLE_0:def 3;
then Y meets (X \/ Z1) \/ Z2 by A13, XBOOLE_0:3;
hence contradiction by A5, XBOOLE_1:70; :: thesis: verum
end;
set V = ((X \/ Z1) \/ Z2) \/ Z3;
A15: ((X \/ Z1) \/ Z2) \/ Z3 = (X \/ (Z1 \/ Z2)) \/ Z3 by XBOOLE_1:4
.= X \/ ((Z1 \/ Z2) \/ Z3) by XBOOLE_1:4 ;
assume A16: for Y being set holds
( not Y in X or ex Y1, Y2, Y3 being set st
( Y1 in Y2 & Y2 in Y3 & Y3 in Y & not Y1 misses X ) ) ; :: thesis: contradiction
now :: thesis: not Y in X
assume A17: Y in X ; :: thesis: contradiction
then consider Y1, Y2, Y3 being set such that
A18: ( Y1 in Y2 & Y2 in Y3 ) and
A19: Y3 in Y and
A20: not Y1 misses X by A16;
Y3 in union X by A17, A19, TARSKI:def 4;
then Y3 in Z1 by A1, A18, A20;
then Y3 in X \/ Z1 by XBOOLE_0:def 3;
then Y3 in (X \/ Z1) \/ Z2 by XBOOLE_0:def 3;
then Y3 in ((X \/ Z1) \/ Z2) \/ Z3 by XBOOLE_0:def 3;
hence contradiction by A5, A19, XBOOLE_0:3; :: thesis: verum
end;
then Y in (Z1 \/ Z2) \/ Z3 by A15, A4, XBOOLE_0:def 3;
then Y in Z1 \/ (Z2 \/ Z3) by XBOOLE_1:4;
then Y in Z2 \/ Z3 by A10, XBOOLE_0:def 3;
then Y in Z3 by A6, XBOOLE_0:def 3;
then Y meets X by A3;
hence contradiction by A15, A5, XBOOLE_1:70; :: thesis: verum