let C be non empty set ; :: thesis: for V being non empty vector-distributive RLSStruct
for f1, f2 being PartFunc of C,V
for f3 being Function of C,REAL holds f3 (#) (f1 + f2) = (f3 (#) f1) + (f3 (#) f2)
let V be non empty vector-distributive RLSStruct ; :: thesis: for f1, f2 being PartFunc of C,V
for f3 being Function of C,REAL holds f3 (#) (f1 + f2) = (f3 (#) f1) + (f3 (#) f2)
let f1, f2 be PartFunc of C,V; :: thesis: for f3 being Function of C,REAL holds f3 (#) (f1 + f2) = (f3 (#) f1) + (f3 (#) f2)
let f3 be Function of C,REAL; :: thesis: f3 (#) (f1 + f2) = (f3 (#) f1) + (f3 (#) f2)
A1: dom (f3 (#) (f1 + f2)) = (dom f3) /\ (dom (f1 + f2)) by Def3
.= (dom f3) /\ ((dom f1) /\ (dom f2)) by Def1
.= (((dom f3) /\ (dom f3)) /\ (dom f1)) /\ (dom f2) by XBOOLE_1:16
.= (((dom f3) /\ (dom f1)) /\ (dom f3)) /\ (dom f2) by XBOOLE_1:16
.= ((dom f3) /\ (dom f1)) /\ ((dom f3) /\ (dom f2)) by XBOOLE_1:16
.= (dom (f3 (#) f1)) /\ ((dom f3) /\ (dom f2)) by Def3
.= (dom (f3 (#) f1)) /\ (dom (f3 (#) f2)) by Def3
.= dom ((f3 (#) f1) + (f3 (#) f2)) by Def1 ;
now :: thesis: for c being Element of C st c in dom (f3 (#) (f1 + f2)) holds
(f3 (#) (f1 + f2)) /. c = ((f3 (#) f1) + (f3 (#) f2)) /. c
let c be Element of C; :: thesis: ( c in dom (f3 (#) (f1 + f2)) implies (f3 (#) (f1 + f2)) /. c = ((f3 (#) f1) + (f3 (#) f2)) /. c )
assume A2: c in dom (f3 (#) (f1 + f2)) ; :: thesis: (f3 (#) (f1 + f2)) /. c = ((f3 (#) f1) + (f3 (#) f2)) /. c
then c in (dom f3) /\ (dom (f1 + f2)) by Def3;
then A3: c in dom (f1 + f2) by XBOOLE_0:def 4;
A4: c in (dom (f3 (#) f1)) /\ (dom (f3 (#) f2)) by A1, A2, Def1;
then A5: c in dom (f3 (#) f1) by XBOOLE_0:def 4;
A6: c in dom (f3 (#) f2) by A4, XBOOLE_0:def 4;
thus (f3 (#) (f1 + f2)) /. c = (f3 . c) * ((f1 + f2) /. c) by A2, Def3
.= (f3 . c) * ((f1 /. c) + (f2 /. c)) by A3, Def1
.= ((f3 . c) * (f1 /. c)) + ((f3 . c) * (f2 /. c)) by RLVECT_1:def 5
.= ((f3 (#) f1) /. c) + ((f3 . c) * (f2 /. c)) by A5, Def3
.= ((f3 (#) f1) /. c) + ((f3 (#) f2) /. c) by A6, Def3
.= ((f3 (#) f1) + (f3 (#) f2)) /. c by A1, A2, Def1 ; :: thesis: verum
end;
hence f3 (#) (f1 + f2) = (f3 (#) f1) + (f3 (#) f2) by A1, PARTFUN2:1; :: thesis: verum