let T be non empty TopSpace; :: thesis:
let F be Subset-Family of T; :: thesis:
assume A1: F is closed-domains-family ; :: thesis:
let X be Subset of (Closed_Domains_Lattice T); :: thesis:
assume A2: X = F ; :: thesis:
thus "\/" (X,(Closed_Domains_Lattice T)) = Cl (union F) :: thesis:

proof

set A = Cl (union F);
Cl (union F) is closed_condensed by A1, Th75;
then Cl (union F) in { C where C is Subset of T : C is closed_condensed } ;
then A3: Cl (union F) in Closed_Domains_of T by TDLAT_1:def 5;
then reconsider a = Cl (union F) as Element of (Closed_Domains_Lattice T) by Th93;
A4: X is_less_than a

proof

let b be Element of (Closed_Domains_Lattice T); :: according to LATTICE3:def 17 :: thesis:
reconsider B = b as Element of Closed_Domains_of T by Th93;
assume b in X ; :: thesis:
then B c= Cl (union F) by A2, Th76;
hence b [= a by A3, Th96; :: thesis:

end;

A5: for b being Element of (Closed_Domains_Lattice T) st X is_less_than b holds
a [= b

proof

let b be Element of (Closed_Domains_Lattice T); :: thesis:
reconsider B = b as Element of Closed_Domains_of T by Th93;
assume A6: X is_less_than b ; :: thesis:
A7: for C being Subset of T st C in F holds
C c= B

proof

let C be Subset of T; :: thesis:
reconsider C1 = C as Subset of T ;
assume A8: C in F ; :: thesis:
then C1 is closed_condensed by A1;
then C in { P where P is Subset of T : P is closed_condensed } ;
then A9: C in Closed_Domains_of T by TDLAT_1:def 5;
then reconsider c = C as Element of (Closed_Domains_Lattice T) by Th93;
c [= b by A2, A6, A8;
hence C c= B by A9, Th96; :: thesis:

end;

B in Closed_Domains_of T ;
then B in { C where C is Subset of T : C is closed_condensed } by TDLAT_1:def 5;
then ex C being Subset of T st
( C = B & C is closed_condensed ) ;
then Cl (union F) c= B by A7, Th76;
hence a [= b by A3, Th96; :: thesis:

end;

Closed_Domains_Lattice T is complete by Th98;
hence "\/" (X,(Closed_Domains_Lattice T)) = Cl (union F) by A4, A5, LATTICE3:def 21; :: thesis:

end;