let Al be QC-alphabet ; :: thesis: for p being Element of CQC-WFF Al
for x being bound_QC-variable of Al
for A being non empty set
for J being interpretation of Al,A
for v being Element of Valuations_in (Al,A) holds
( J,v |= All (x,p) iff for a being Element of A holds J,v . (x | a) |= p )
let p be Element of CQC-WFF Al; :: thesis: for x being bound_QC-variable of Al
for A being non empty set
for J being interpretation of Al,A
for v being Element of Valuations_in (Al,A) holds
( J,v |= All (x,p) iff for a being Element of A holds J,v . (x | a) |= p )
let x be bound_QC-variable of Al; :: thesis: for A being non empty set
for J being interpretation of Al,A
for v being Element of Valuations_in (Al,A) holds
( J,v |= All (x,p) iff for a being Element of A holds J,v . (x | a) |= p )
let A be non empty set ; :: thesis: for J being interpretation of Al,A
for v being Element of Valuations_in (Al,A) holds
( J,v |= All (x,p) iff for a being Element of A holds J,v . (x | a) |= p )
let J be interpretation of Al,A; :: thesis: for v being Element of Valuations_in (Al,A) holds
( J,v |= All (x,p) iff for a being Element of A holds J,v . (x | a) |= p )
let v be Element of Valuations_in (Al,A); :: thesis: ( J,v |= All (x,p) iff for a being Element of A holds J,v . (x | a) |= p )
thus ( J,v |= All (x,p) implies for a being Element of A holds J,v . (x | a) |= p ) :: thesis: ( ( for a being Element of A holds J,v . (x | a) |= p ) implies J,v |= All (x,p) )
proof
assume A1: J,v |= All (x,p) ; :: thesis: for a being Element of A holds J,v . (x | a) |= p
let a be Element of A; :: thesis: J,v . (x | a) |= p
for y being bound_QC-variable of Al st x <> y holds
(v . (x | a)) . y = v . y by Th48;
hence J,v . (x | a) |= p by A1, VALUAT_1:29; :: thesis: verum
end;
thus ( ( for a being Element of A holds J,v . (x | a) |= p ) implies J,v |= All (x,p) ) :: thesis: verum
proof
assume A2: for a being Element of A holds J,v . (x | a) |= p ; :: thesis: J,v |= All (x,p)
for w being Element of Valuations_in (Al,A) st ( for y being bound_QC-variable of Al st x <> y holds
w . y = v . y ) holds
J,w |= p
proof
let w be Element of Valuations_in (Al,A); :: thesis: ( ( for y being bound_QC-variable of Al st x <> y holds
w . y = v . y ) implies J,w |= p )
assume A3: for y being bound_QC-variable of Al st x <> y holds
w . y = v . y ; :: thesis: J,w |= p
set c = w . x;
A4: for b being object st b in dom w holds
w . b = (v . (x | (w . x))) . b
proof
let b be object ; :: thesis: ( b in dom w implies w . b = (v . (x | (w . x))) . b )
assume b in dom w ; :: thesis: w . b = (v . (x | (w . x))) . b
then reconsider y = b as bound_QC-variable of Al ;
now :: thesis: ( x <> y implies w . b = (v . (x | (w . x))) . b )
assume A5: x <> y ; :: thesis: w . b = (v . (x | (w . x))) . b
then w . y = v . y by A3;
hence w . b = (v . (x | (w . x))) . b by A5, Th48; :: thesis: verum
end;
hence w . b = (v . (x | (w . x))) . b by Th49; :: thesis: verum
end;
v . (x | (w . x)) is Element of Funcs ((bound_QC-variables Al),A) by VALUAT_1:def 1;
then A6: ex f being Function st
( v . (x | (w . x)) = f & dom f = bound_QC-variables Al & rng f c= A ) by FUNCT_2:def 2;
w is Element of Funcs ((bound_QC-variables Al),A) by VALUAT_1:def 1;
then ex f being Function st
( w = f & dom f = bound_QC-variables Al & rng f c= A ) by FUNCT_2:def 2;
then v . (x | (w . x)) = w by A4, A6, FUNCT_1:2;
hence J,w |= p by A2; :: thesis: verum
end;
hence J,v |= All (x,p) by VALUAT_1:29; :: thesis: verum
end;