let p be Real; :: thesis: ( cos is_differentiable_in p & diff (cos,p) = - (sin . p) )
reconsider p = p as Element of REAL by XREAL_0:def 1;
deffunc H2( Real) -> Element of REAL = In ((- ($1 * (Im ((Sum (($1 * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>)))))),REAL);
consider Cr being Function of REAL,REAL such that
A1: for th being Element of REAL holds Cr . th = H2(th) from FUNCT_2:sch 4();
 for hy1 being non-zero 0 -convergent Real_Sequence holds
( (hy1 ") (#) (Cr /* hy1) is convergent & lim ((hy1 ") (#) (Cr /* hy1)) = 0 )
proof
let hy1 be non-zero 0 -convergent Real_Sequence; :: thesis: ( (hy1 ") (#) (Cr /* hy1) is convergent & lim ((hy1 ") (#) (Cr /* hy1)) = 0 )
A2: for n being Nat holds ((hy1 ") (#) (Cr /* hy1)) . n = - (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>))))
proof
let n be Nat; :: thesis: ((hy1 ") (#) (Cr /* hy1)) . n = - (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>))))
A3: n in NAT by ORDINAL1:def 12;
A4: ((hy1 ") (#) (Cr /* hy1)) . n = ((hy1 ") . n) * ((Cr /* hy1) . n) by SEQ_1:8
.= ((hy1 . n) ") * ((Cr /* hy1) . n) by VALUED_1:10 ;
dom Cr = REAL by FUNCT_2:def 1;
then rng hy1 c= dom Cr ;
then A5: ((hy1 ") (#) (Cr /* hy1)) . n = ((hy1 . n) ") * (Cr . (hy1 . n)) by A4, FUNCT_2:108, A3
.= ((hy1 . n) ") * H2(hy1 . n) by A1
.= - ((((hy1 . n) ") * (hy1 . n)) * (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>))))) ;
hy1 . n <> 0 by SEQ_1:5;
then ((hy1 ") (#) (Cr /* hy1)) . n = - (1 * (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>))))) by A5, XCMPLX_0:def 7
.= - (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>)))) ;
hence ((hy1 ") (#) (Cr /* hy1)) . n = - (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>)))) ; :: thesis: verum
end;
deffunc H3( Real) -> Element of REAL = - (Im ((Sum (((hy1 . $1) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>))));
consider rseq being Real_Sequence such that
A6: for n being Nat holds rseq . n = H3(n) from SEQ_1:sch 1();
 deffunc H4( Nat) -> set = (Sum (((hy1 . $1) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>));
consider cq1 being Complex_Sequence such that
A7: for n being Nat holds cq1 . n = H4(n) from COMSEQ_1:sch 1();
 A8: for q being Real st q > 0 holds
ex k being Nat st
for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q
proof
let q be Real; :: thesis: ( q > 0 implies ex k being Nat st
for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q )
assume A9: q > 0 ; :: thesis: ex k being Nat st
for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q
ex k being Nat st
for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q
proof
consider r being Real such that
A10: r > 0 and
A11: for z being Complex st |.z.| < r holds
|.(Sum (z P_dt)).| < q by A9, Th57;
( hy1 is convergent & lim hy1 = 0 ) ;
then consider k being Nat such that
A12: for m being Nat st k <= m holds
|.((hy1 . m) - 0).| < r by A10, SEQ_2:def 7;
A13: now :: thesis: for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q
let m be Nat; :: thesis: ( k <= m implies |.((cq1 . m) - 0c).| < q )
assume A14: k <= m ; :: thesis: |.((cq1 . m) - 0c).| < q
A15: |.((cq1 . m) - 0c).| = |.((Sum (((hy1 . m) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>))).| by A7
.= |.(Sum (((hy1 . m) * <i>) P_dt)).| * |.((cos . p) + ((sin . p) * <i>)).| by COMPLEX1:65
.= |.(Sum (((hy1 . m) * <i>) P_dt)).| * |.(Sum ((p * <i>) ExpSeq)).| by Lm3
.= |.(Sum (((hy1 . m) * <i>) P_dt)).| * 1 by Lm5
.= |.(Sum (((hy1 . m) * <i>) P_dt)).| ;
A16: |.((hy1 . m) - 0).| < r by A12, A14;
(hy1 . m) * <i> = 0 + ((hy1 . m) * <i>) ;
then ( Re ((hy1 . m) * <i>) = 0 & Im ((hy1 . m) * <i>) = hy1 . m ) by COMPLEX1:12;
then |.((hy1 . m) * <i>).| = |.(hy1 . m).| by COMPLEX1:72;
hence |.((cq1 . m) - 0c).| < q by A11, A15, A16; :: thesis: verum
end;
take k ; :: thesis: for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q
thus for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q by A13; :: thesis: verum
end;
hence ex k being Nat st
for m being Nat st k <= m holds
|.((cq1 . m) - 0c).| < q ; :: thesis: verum
end;
then A17: cq1 is convergent by COMSEQ_2:def 5;
then lim cq1 = 0c by A8, COMSEQ_2:def 6;
then A18: lim (- cq1) = - 0c by A17, COMSEQ_2:22;
A19: for n being Element of NAT holds (Im (- cq1)) . n = rseq . n
proof
A20: for n being Nat holds (Im (- cq1)) . n = - (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>))))
proof
let n be Nat; :: thesis: (Im (- cq1)) . n = - (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>))))
(Im (- cq1)) . n = Im ((- cq1) . n) by COMSEQ_3:def 6
.= Im (- (cq1 . n)) by VALUED_1:8
.= Im (- ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>)))) by A7
.= - (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>)))) by COMPLEX1:17 ;
hence (Im (- cq1)) . n = - (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>)))) ; :: thesis: verum
end;
let n be Nat; :: thesis: ( n is Element of NAT implies (Im (- cq1)) . n = rseq . n )
rseq . n = - (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>)))) by A6;
hence ( n is Element of NAT implies (Im (- cq1)) . n = rseq . n ) by A20; :: thesis: verum
end;
for n being Element of NAT holds rseq . n = ((hy1 ") (#) (Cr /* hy1)) . n
proof
let n be Element of NAT ; :: thesis: rseq . n = ((hy1 ") (#) (Cr /* hy1)) . n
rseq . n = - (Im ((Sum (((hy1 . n) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>)))) by A6;
hence rseq . n = ((hy1 ") (#) (Cr /* hy1)) . n by A2; :: thesis: verum
end;
then rseq = (hy1 ") (#) (Cr /* hy1) ;
then (hy1 ") (#) (Cr /* hy1) = Im (- cq1) by A19;
hence ( (hy1 ") (#) (Cr /* hy1) is convergent & lim ((hy1 ") (#) (Cr /* hy1)) = 0 ) by A17, A18, COMPLEX1:4, COMSEQ_3:41; :: thesis: verum
end;
then reconsider PR = Cr as RestFunc by FDIFF_1:def 2;
deffunc H3( Real) -> Element of REAL = In ((- ($1 * (sin . p))),REAL);
consider CL being Function of REAL,REAL such that
A21: for th being Element of REAL holds CL . th = H3(th) from FUNCT_2:sch 4();
 ex r being Real st
for q being Real holds CL . q = r * q
proof
A22: for q being Real holds CL . q = (- (sin . p)) * q
proof
let q be Real; :: thesis: CL . q = (- (sin . p)) * q
reconsider qq = q as Element of REAL by XREAL_0:def 1;
CL . qq = H3(q) by A21
.= (- (sin . p)) * q ;
hence CL . q = (- (sin . p)) * q ; :: thesis: verum
end;
take - (sin . p) ; :: thesis: for q being Real holds CL . q = (- (sin . p)) * q
thus for q being Real holds CL . q = (- (sin . p)) * q by A22; :: thesis: verum
end;
then reconsider PL = CL as LinearFunc by FDIFF_1:def 3;
A23: ex N being Neighbourhood of p st
( N c= dom cos & ( for r being Real st r in N holds
(cos . r) - (cos . p) = (PL . (r - p)) + (PR . (r - p)) ) )
proof
A24: for r being Real st r in ].(p - 1),(p + 1).[ holds
(cos . r) - (cos . p) = (PL . (r - p)) + (PR . (r - p))
proof
let r be Real; :: thesis: ( r in ].(p - 1),(p + 1).[ implies (cos . r) - (cos . p) = (PL . (r - p)) + (PR . (r - p)) )
A25: r - p in REAL by XREAL_0:def 1;
r = p + (r - p) ;
then (cos . r) - (cos . p) = (- ((r - p) * (sin . p))) - ((r - p) * (Im ((Sum (((r - p) * <i>) P_dt)) * ((cos . p) + ((sin . p) * <i>))))) by Th59
.= (- ((r - p) * (sin . p))) + H2(r - p)
.= (- ((r - p) * (sin . p))) + (Cr . (r - p)) by A1, A25
.= H3(r - p) + (Cr . (r - p))
.= (PL . (r - p)) + (PR . (r - p)) by A21, A25 ;
hence ( r in ].(p - 1),(p + 1).[ implies (cos . r) - (cos . p) = (PL . (r - p)) + (PR . (r - p)) ) ; :: thesis: verum
end;
take ].(p - 1),(p + 1).[ ; :: thesis: ( ].(p - 1),(p + 1).[ is Neighbourhood of p & ].(p - 1),(p + 1).[ c= dom cos & ( for r being Real st r in ].(p - 1),(p + 1).[ holds
(cos . r) - (cos . p) = (PL . (r - p)) + (PR . (r - p)) ) )
thus ( ].(p - 1),(p + 1).[ is Neighbourhood of p & ].(p - 1),(p + 1).[ c= dom cos & ( for r being Real st r in ].(p - 1),(p + 1).[ holds
(cos . r) - (cos . p) = (PL . (r - p)) + (PR . (r - p)) ) ) by A24, Th24, RCOMP_1:def 6; :: thesis: verum
end;
then A26: cos is_differentiable_in p by FDIFF_1:def 4;
PL . jj = H3(1) by A21
.= - (sin . p) ;
hence ( cos is_differentiable_in p & diff (cos,p) = - (sin . p) ) by A23, A26, FDIFF_1:def 5; :: thesis: verum