let V be RealUnitarySpace; :: thesis:
let A, B be Subset of V; :: thesis:

now :: thesis:

deffunc H₁( object ) -> Element of omega = 0 ;
let v be VECTOR of V; :: thesis:
assume v in Lin (A \/ B) ; :: thesis:
then consider l being Linear_Combination of A \/ B such that
A1: v = Sum l by Th1;
deffunc H₂( object ) -> set = l . $1;
set D = (Carrier l) \ A;
set C = (Carrier l) /\ A;
defpred S₁[ object ] means $1 in (Carrier l) /\ A;
defpred S₂[ object ] means $1 in (Carrier l) \ A;

now :: thesis:

let x be set ; :: thesis:
assume x in the carrier of V ; :: thesis:
then reconsider v = x as VECTOR of V ;
for f being Function of the carrier of V,REAL holds f . v in REAL ;
hence ( x in (Carrier l) /\ A implies l . x in REAL ) ; :: thesis:
assume not x in (Carrier l) /\ A ; :: thesis:
thus 0 in REAL by XREAL_0:def 1; :: thesis:

end;

then A2: for x being object st x in the carrier of V holds
( ( S₁[x] implies H₂(x) in REAL ) & ( not S₁[x] implies H₁(x) in REAL ) ) ;
consider f being Function of the carrier of V,REAL such that
A3: for x being object st x in the carrier of V holds
( ( S₁[x] implies f . x = H₂(x) ) & ( not S₁[x] implies f . x = H₁(x) ) ) from FUNCT_2:sch 5(A2);
reconsider C = (Carrier l) /\ A as finite Subset of V ;
reconsider f = f as Element of Funcs ( the carrier of V,REAL) by FUNCT_2:8;
for u being VECTOR of V st not u in C holds
f . u = 0 by A3;
then reconsider f = f as Linear_Combination of V by RLVECT_2:def 3;
A4: Carrier f c= C

proof

let x be object ; :: according to TARSKI:def 3 :: thesis:
assume x in Carrier f ; :: thesis:
then A5: ex u being VECTOR of V st
( x = u & f . u <> 0 ) ;
assume not x in C ; :: thesis:
hence contradiction by A3, A5; :: thesis:

end;

C c= A by XBOOLE_1:17;
then Carrier f c= A by A4;
then reconsider f = f as Linear_Combination of A by RLVECT_2:def 6;

now :: thesis:

let x be set ; :: thesis:
assume x in the carrier of V ; :: thesis:
then reconsider v = x as VECTOR of V ;
for g being Function of the carrier of V,REAL holds g . v in REAL ;
hence ( x in (Carrier l) \ A implies l . x in REAL ) ; :: thesis:
assume not x in (Carrier l) \ A ; :: thesis:
thus 0 in REAL by XREAL_0:def 1; :: thesis:

end;

then A6: for x being object st x in the carrier of V holds
( ( S₂[x] implies H₂(x) in REAL ) & ( not S₂[x] implies H₁(x) in REAL ) ) ;
consider g being Function of the carrier of V,REAL such that
A7: for x being object st x in the carrier of V holds
( ( S₂[x] implies g . x = H₂(x) ) & ( not S₂[x] implies g . x = H₁(x) ) ) from FUNCT_2:sch 5(A6);
reconsider D = (Carrier l) \ A as finite Subset of V ;
reconsider g = g as Element of Funcs ( the carrier of V,REAL) by FUNCT_2:8;
for u being VECTOR of V st not u in D holds
g . u = 0 by A7;
then reconsider g = g as Linear_Combination of V by RLVECT_2:def 3;
A8: D c= B

proof

let x be object ; :: according to TARSKI:def 3 :: thesis:
assume x in D ; :: thesis:
then A9: ( x in Carrier l & not x in A ) by XBOOLE_0:def 5;
Carrier l c= A \/ B by RLVECT_2:def 6;
hence x in B by A9, XBOOLE_0:def 3; :: thesis:

end;

Carrier g c= D

proof

let x be object ; :: according to TARSKI:def 3 :: thesis:
assume x in Carrier g ; :: thesis:
then A10: ex u being VECTOR of V st
( x = u & g . u <> 0 ) ;
assume not x in D ; :: thesis:
hence contradiction by A7, A10; :: thesis:

end;

then Carrier g c= B by A8;
then reconsider g = g as Linear_Combination of B by RLVECT_2:def 6;
l = f + g

proof

let v be VECTOR of V; :: according to RLVECT_2:def 9 :: thesis:

now :: thesis:

per cases ;

suppose A11: v in C ; :: thesis:

A12: now :: thesis:

assume v in D ; :: thesis:
then not v in A by XBOOLE_0:def 5;
hence contradiction by A11, XBOOLE_0:def 4; :: thesis:

end;

thus (f + g) . v = (f . v) + (g . v) by RLVECT_2:def 10
.= (l . v) + (g . v) by A3, A11
.= (l . v) + 0 by A7, A12
.= l . v ; :: thesis:

end;

suppose A13: not v in C ; :: thesis:

now :: thesis:

per cases ;

suppose A14: v in Carrier l ; :: thesis:

A15: now :: thesis:

assume not v in D ; :: thesis:
then ( not v in Carrier l or v in A ) by XBOOLE_0:def 5;
hence contradiction by A13, A14, XBOOLE_0:def 4; :: thesis:

end;

thus (f + g) . v = (f . v) + (g . v) by RLVECT_2:def 10
.= 0 + (g . v) by A3, A13
.= l . v by A7, A15 ; :: thesis:

end;

suppose A16: not v in Carrier l ; :: thesis:

then A17: not v in D by XBOOLE_0:def 5;
A18: not v in C by A16, XBOOLE_0:def 4;
thus (f + g) . v = (f . v) + (g . v) by RLVECT_2:def 10
.= 0 + (g . v) by A3, A18
.= 0 + 0 by A7, A17
.= l . v by A16 ; :: thesis:

end;

hence l . v = (f + g) . v ; :: thesis:

end;

hence l . v = (f + g) . v ; :: thesis:

end;

then A19: v = (Sum f) + (Sum g) by A1, RLVECT_3:1;
( Sum f in Lin A & Sum g in Lin B ) by Th1;
hence v in (Lin A) + (Lin B) by A19, RUSUB_2:1; :: thesis:

end;

then A20: Lin (A \/ B) is Subspace of (Lin A) + (Lin B) by RUSUB_1:23;
( Lin A is Subspace of Lin (A \/ B) & Lin B is Subspace of Lin (A \/ B) ) by Th7, XBOOLE_1:7;
then (Lin A) + (Lin B) is Subspace of Lin (A \/ B) by Lm5;
hence Lin (A \/ B) = (Lin A) + (Lin B) by A20, RUSUB_1:20; :: thesis: