let C, D be Category; :: thesis: for S being Functor of C,D holds S *' is Contravariant_Functor of C,D opp
let S be Functor of C,D; :: thesis: S *' is Contravariant_Functor of C,D opp
thus for c being Object of C ex d being Object of (D opp) st (S *') . (id c) = id d :: according to OPPCAT_1:def 9 :: thesis: ( ( for f being Morphism of C holds
( (S *') . (id (dom f)) = id (cod ((S *') . f)) & (S *') . (id (cod f)) = id (dom ((S *') . f)) ) ) & ( for f, g being Morphism of C st dom g = cod f holds
(S *') . (g (*) f) = ((S *') . f) (*) ((S *') . g) ) )
proof
let c be Object of C; :: thesis: ex d being Object of (D opp) st (S *') . (id c) = id d
(S *') . (id c) = id ((Obj (S *')) . c) by Lm25;
hence ex d being Object of (D opp) st (S *') . (id c) = id d ; :: thesis: verum
end;
thus for f being Morphism of C holds
( (S *') . (id (dom f)) = id (cod ((S *') . f)) & (S *') . (id (cod f)) = id (dom ((S *') . f)) ) :: thesis: for f, g being Morphism of C st dom g = cod f holds
(S *') . (g (*) f) = ((S *') . f) (*) ((S *') . g)
proof
let f be Morphism of C; :: thesis: ( (S *') . (id (dom f)) = id (cod ((S *') . f)) & (S *') . (id (cod f)) = id (dom ((S *') . f)) )
thus (S *') . (id (dom f)) = id ((Obj (S *')) . (dom f)) by Lm25
.= id (cod ((S *') . f)) by Lm26 ; :: thesis: (S *') . (id (cod f)) = id (dom ((S *') . f))
thus (S *') . (id (cod f)) = id ((Obj (S *')) . (cod f)) by Lm25
.= id (dom ((S *') . f)) by Lm26 ; :: thesis: verum
end;
let f, g be Morphism of C; :: thesis: ( dom g = cod f implies (S *') . (g (*) f) = ((S *') . f) (*) ((S *') . g) )
assume A1: dom g = cod f ; :: thesis: (S *') . (g (*) f) = ((S *') . f) (*) ((S *') . g)
then A2: dom (S . g) = cod (S . f) by CAT_1:64;
reconsider Sff = S . f as Morphism of dom (S . f), cod (S . f) by CAT_1:4;
reconsider Sgg = S . g as Morphism of dom (S . g), cod (S . g) by CAT_1:4;
A3: ( Hom ((dom (S . f)),(cod (S . f))) <> {} & Hom ((dom (S . g)),(cod (S . g))) <> {} ) by CAT_1:2;
then A4: Sff opp = (S . f) opp by Def6;
A5: Sgg opp = (S . g) opp by Def6, A3;
thus (S *') . (g (*) f) = (S . (g (*) f)) opp by Def11
.= (Sgg (*) Sff) opp by A1, CAT_1:64
.= (Sff opp) (*) (Sgg opp) by A2, Th14, A3
.= ((S *') . f) (*) ((S . g) opp) by Def11, A4, A5
.= ((S *') . f) (*) ((S *') . g) by Def11 ; :: thesis: verum