let R be Skew-Field; :: thesis: for V being LeftMod of R
for v1, v2 being Vector of V holds
( ( v1 <> v2 & {v1,v2} is linearly-independent ) iff for a, b being Scalar of R st (a * v1) + (b * v2) = 0. V holds
( a = 0. R & b = 0. R ) )
let V be LeftMod of R; :: thesis: for v1, v2 being Vector of V holds
( ( v1 <> v2 & {v1,v2} is linearly-independent ) iff for a, b being Scalar of R st (a * v1) + (b * v2) = 0. V holds
( a = 0. R & b = 0. R ) )
let v1, v2 be Vector of V; :: thesis: ( ( v1 <> v2 & {v1,v2} is linearly-independent ) iff for a, b being Scalar of R st (a * v1) + (b * v2) = 0. V holds
( a = 0. R & b = 0. R ) )
thus ( v1 <> v2 & {v1,v2} is linearly-independent implies for a, b being Scalar of R st (a * v1) + (b * v2) = 0. V holds
( a = 0. R & b = 0. R ) ) :: thesis: ( ( for a, b being Scalar of R st (a * v1) + (b * v2) = 0. V holds
( a = 0. R & b = 0. R ) ) implies ( v1 <> v2 & {v1,v2} is linearly-independent ) )
proof
assume A1: ( v1 <> v2 & {v1,v2} is linearly-independent ) ; :: thesis: for a, b being Scalar of R st (a * v1) + (b * v2) = 0. V holds
( a = 0. R & b = 0. R )
let a, b be Scalar of R; :: thesis: ( (a * v1) + (b * v2) = 0. V implies ( a = 0. R & b = 0. R ) )
assume that
A2: (a * v1) + (b * v2) = 0. V and
A3: ( a <> 0. R or b <> 0. R ) ; :: thesis: contradiction
now :: thesis: contradiction
per cases ( a <> 0. R or b <> 0. R ) by A3;
suppose A4: a <> 0. R ; :: thesis: contradiction
0. V = (a ") * ((a * v1) + (b * v2)) by A2, VECTSP_2:30
.= ((a ") * (a * v1)) + ((a ") * (b * v2)) by VECTSP_1:def 14
.= (((a ") * a) * v1) + ((a ") * (b * v2)) by VECTSP_1:def 16
.= (((a ") * a) * v1) + (((a ") * b) * v2) by VECTSP_1:def 16
.= ((1. R) * v1) + (((a ") * b) * v2) by A4, Lm2
.= v1 + (((a ") * b) * v2) by VECTSP_1:def 17 ;
then v1 = - (((a ") * b) * v2) by VECTSP_1:16
.= (- (1. R)) * (((a ") * b) * v2) by VECTSP_1:14
.= ((- (1. R)) * ((a ") * b)) * v2 by VECTSP_1:def 16 ;
hence contradiction by A1, Th16; :: thesis: verum
end;
suppose A5: b <> 0. R ; :: thesis: contradiction
0. V = (b ") * ((a * v1) + (b * v2)) by A2, VECTSP_2:30
.= ((b ") * (a * v1)) + ((b ") * (b * v2)) by VECTSP_1:def 14
.= (((b ") * a) * v1) + ((b ") * (b * v2)) by VECTSP_1:def 16
.= (((b ") * a) * v1) + ((1. R) * v2) by A5, Lm2
.= (((b ") * a) * v1) + v2 by VECTSP_1:def 17 ;
then v2 = - (((b ") * a) * v1) by VECTSP_1:16
.= (- (1. R)) * (((b ") * a) * v1) by VECTSP_1:14
.= ((- (1. R)) * ((b ") * a)) * v1 by VECTSP_1:def 16 ;
hence contradiction by A1, Th16; :: thesis: verum
end;
end;
end;
hence contradiction ; :: thesis: verum
end;
assume A6: for a, b being Scalar of R st (a * v1) + (b * v2) = 0. V holds
( a = 0. R & b = 0. R ) ; :: thesis: ( v1 <> v2 & {v1,v2} is linearly-independent )
A7: now :: thesis: for a being Scalar of R holds not v1 = a * v2
let a be Scalar of R; :: thesis: not v1 = a * v2
assume v1 = a * v2 ; :: thesis: contradiction
then v1 = (0. V) + (a * v2) by RLVECT_1:def 4;
then 0. V = v1 - (a * v2) by RLSUB_2:61
.= v1 + ((- a) * v2) by VECTSP_1:21
.= ((1. R) * v1) + ((- a) * v2) by VECTSP_1:def 17 ;
hence contradiction by A6; :: thesis: verum
end;
now :: thesis: not v2 = 0. V
assume A8: v2 = 0. V ; :: thesis: contradiction
0. V = (0. V) + (0. V) by RLVECT_1:def 4
.= ((0. R) * v1) + (0. V) by VECTSP_2:30
.= ((0. R) * v1) + ((1. R) * v2) by A8, VECTSP_2:30 ;
hence contradiction by A6; :: thesis: verum
end;
hence ( v1 <> v2 & {v1,v2} is linearly-independent ) by A7, Th16; :: thesis: verum