let X be RealNormSpace-Sequence; :: thesis: for Y being RealNormSpace
for f being Point of (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) st f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) holds
0 = ||.f.||
let Y be RealNormSpace; :: thesis: for f being Point of (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) st f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) holds
0 = ||.f.||
let f be Point of (R_NormSpace_of_BoundedMultilinearOperators (X,Y)); :: thesis: ( f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) implies 0 = ||.f.|| )
assume A1: f = 0. (R_NormSpace_of_BoundedMultilinearOperators (X,Y)) ; :: thesis: 0 = ||.f.||
reconsider g = f as Lipschitzian MultilinearOperator of X,Y by Def9;
set z = the carrier of (product X) --> (0. Y);
reconsider z = the carrier of (product X) --> (0. Y) as Function of the carrier of (product X), the carrier of Y ;
consider r0 being object such that
A2: r0 in PreNorms g by XBOOLE_0:def 1;
reconsider r0 = r0 as Real by A2;
A3: ( ( for s being Real st s in PreNorms g holds
s <= 0 ) implies upper_bound (PreNorms g) <= 0 ) by SEQ_4:45;
A4: ( not PreNorms g is empty & PreNorms g is bounded_above ) by Th27;
A5: z = g by A1, Th31;
A6: now :: thesis: for r being Real st r in PreNorms g holds
( 0 <= r & r <= 0 )
let r be Real; :: thesis: ( r in PreNorms g implies ( 0 <= r & r <= 0 ) )
assume r in PreNorms g ; :: thesis: ( 0 <= r & r <= 0 )
then consider t being VECTOR of (product X) such that
A7: r = ||.(g . t).|| and
for i being Element of dom X holds ||.(t . i).|| <= 1 ;
||.(g . t).|| = ||.(0. Y).|| by A5, FUNCOP_1:7
.= 0 ;
hence ( 0 <= r & r <= 0 ) by A7; :: thesis: verum
end;
then 0 <= r0 by A2;
then upper_bound (PreNorms g) = 0 by A6, A4, A2, A3, SEQ_4:def 1;
hence 0 = ||.f.|| by Th30; :: thesis: verum