let x0 be Real; :: thesis: for f being PartFunc of REAL,REAL st f is_convergent_in x0 holds
( abs f is_convergent_in x0 & lim ((abs f),x0) = |.(lim (f,x0)).| )
let f be PartFunc of REAL,REAL; :: thesis: ( f is_convergent_in x0 implies ( abs f is_convergent_in x0 & lim ((abs f),x0) = |.(lim (f,x0)).| ) )
assume A1: f is_convergent_in x0 ; :: thesis: ( abs f is_convergent_in x0 & lim ((abs f),x0) = |.(lim (f,x0)).| )
A2: now :: thesis: for seq being Real_Sequence st seq is convergent & lim seq = x0 & rng seq c= (dom (abs f)) \ {x0} holds
( (abs f) /* seq is convergent & lim ((abs f) /* seq) = |.(lim (f,x0)).| )
let seq be Real_Sequence; :: thesis: ( seq is convergent & lim seq = x0 & rng seq c= (dom (abs f)) \ {x0} implies ( (abs f) /* seq is convergent & lim ((abs f) /* seq) = |.(lim (f,x0)).| ) )
assume that
A3: seq is convergent and
A4: lim seq = x0 and
A5: rng seq c= (dom (abs f)) \ {x0} ; :: thesis: ( (abs f) /* seq is convergent & lim ((abs f) /* seq) = |.(lim (f,x0)).| )
A6: rng seq c= (dom f) \ {x0} by A5, VALUED_1:def 11;
then rng seq c= dom f by XBOOLE_1:1;
then A7: abs (f /* seq) = (abs f) /* seq by RFUNCT_2:10;
A8: f /* seq is convergent by A1, A3, A4, A6;
hence (abs f) /* seq is convergent by A7; :: thesis: lim ((abs f) /* seq) = |.(lim (f,x0)).|
lim (f /* seq) = lim (f,x0) by A1, A3, A4, A6, Def4;
hence lim ((abs f) /* seq) = |.(lim (f,x0)).| by A8, A7, SEQ_4:14; :: thesis: verum
end;
now :: thesis: for r1, r2 being Real st r1 < x0 & x0 < r2 holds
ex g1, g2 being Real st
( r1 < g1 & g1 < x0 & g1 in dom (abs f) & g2 < r2 & x0 < g2 & g2 in dom (abs f) )
let r1, r2 be Real; :: thesis: ( r1 < x0 & x0 < r2 implies ex g1, g2 being Real st
( r1 < g1 & g1 < x0 & g1 in dom (abs f) & g2 < r2 & x0 < g2 & g2 in dom (abs f) ) )
assume that
A9: r1 < x0 and
A10: x0 < r2 ; :: thesis: ex g1, g2 being Real st
( r1 < g1 & g1 < x0 & g1 in dom (abs f) & g2 < r2 & x0 < g2 & g2 in dom (abs f) )
consider g1, g2 being Real such that
A11: r1 < g1 and
A12: g1 < x0 and
A13: g1 in dom f and
A14: g2 < r2 and
A15: x0 < g2 and
A16: g2 in dom f by A1, A9, A10;
take g1 = g1; :: thesis: ex g2 being Real st
( r1 < g1 & g1 < x0 & g1 in dom (abs f) & g2 < r2 & x0 < g2 & g2 in dom (abs f) )
take g2 = g2; :: thesis: ( r1 < g1 & g1 < x0 & g1 in dom (abs f) & g2 < r2 & x0 < g2 & g2 in dom (abs f) )
thus ( r1 < g1 & g1 < x0 & g1 in dom (abs f) & g2 < r2 & x0 < g2 & g2 in dom (abs f) ) by A11, A12, A13, A14, A15, A16, VALUED_1:def 11; :: thesis: verum
end;
hence abs f is_convergent_in x0 by A2; :: thesis: lim ((abs f),x0) = |.(lim (f,x0)).|
hence lim ((abs f),x0) = |.(lim (f,x0)).| by A2, Def4; :: thesis: verum