let G be Group; :: thesis: for H being strict Subgroup of G holds card (con_class H) = Index (Normalizer H)
let H be strict Subgroup of G; :: thesis: card (con_class H) = Index (Normalizer H)
defpred S1[ object , object ] means ex H1 being strict Subgroup of G st
( $1 = H1 & $2 = carr H1 );
A1: for x being object st x in con_class H holds
ex y being object st S1[x,y]
proof
let x be object ; :: thesis: ( x in con_class H implies ex y being object st S1[x,y] )
assume x in con_class H ; :: thesis: ex y being object st S1[x,y]
then reconsider H = x as strict Subgroup of G by Def1;
reconsider y = carr H as set ;
take y ; :: thesis: S1[x,y]
take H ; :: thesis: ( x = H & y = carr H )
thus ( x = H & y = carr H ) ; :: thesis: verum
end;
consider f being Function such that
A2: dom f = con_class H and
A3: for x being object st x in con_class H holds
S1[x,f . x] from CLASSES1:sch 1(A1);
 A4: rng f = con_class (carr H)
proof
thus rng f c= con_class (carr H) :: according to XBOOLE_0:def 10 :: thesis: con_class (carr H) c= rng f
proof
let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in rng f or x in con_class (carr H) )
assume x in rng f ; :: thesis: x in con_class (carr H)
then consider y being object such that
A5: y in dom f and
A6: f . y = x by FUNCT_1:def 3;
consider H1 being strict Subgroup of G such that
A7: y = H1 and
A8: x = carr H1 by A2, A3, A5, A6;
H1,H are_conjugated by A2, A5, A7, Th107;
then carr H1, carr H are_conjugated by Th113;
hence x in con_class (carr H) by A8; :: thesis: verum
end;
let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in con_class (carr H) or x in rng f )
assume x in con_class (carr H) ; :: thesis: x in rng f
then consider B being Subset of G such that
A9: B = x and
A10: carr H,B are_conjugated ;
consider H1 being strict Subgroup of G such that
A11: the carrier of H1 = B by A10, Th93;
B = carr H1 by A11;
then H1,H are_conjugated by A10, Th113;
then A12: H1 in con_class H by Th107;
then ex H2 being strict Subgroup of G st
( H1 = H2 & f . H1 = carr H2 ) by A3;
hence x in rng f by A2, A9, A11, A12, FUNCT_1:def 3; :: thesis: verum
end;
f is one-to-one
proof
let x, y be object ; :: according to FUNCT_1:def 4 :: thesis: ( not x in dom f or not y in dom f or not f . x = f . y or x = y )
assume that
A13: ( x in dom f & y in dom f ) and
A14: f . x = f . y ; :: thesis: x = y
( ex H1 being strict Subgroup of G st
( x = H1 & f . x = carr H1 ) & ex H2 being strict Subgroup of G st
( y = H2 & f . y = carr H2 ) ) by A2, A3, A13;
hence x = y by A14, GROUP_2:59; :: thesis: verum
end;
then con_class H, con_class (carr H) are_equipotent by A2, A4, WELLORD2:def 4;
hence card (con_class H) = card (con_class (carr H)) by CARD_1:5
.= Index (Normalizer H) by Th130 ;
:: thesis: verum