let G be addGroup; :: thesis: for a being Element of G
for H1, H2 being Subgroup of G holds a + (H1 /\ H2) = (a + H1) /\ (a + H2)
let a be Element of G; :: thesis: for H1, H2 being Subgroup of G holds a + (H1 /\ H2) = (a + H1) /\ (a + H2)
let H1, H2 be Subgroup of G; :: thesis: a + (H1 /\ H2) = (a + H1) /\ (a + H2)
thus a + (H1 /\ H2) c= (a + H1) /\ (a + H2) :: according to XBOOLE_0:def 10 :: thesis: (a + H1) /\ (a + H2) c= a + (H1 /\ H2)
proof
let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in a + (H1 /\ H2) or x in (a + H1) /\ (a + H2) )
assume x in a + (H1 /\ H2) ; :: thesis: x in (a + H1) /\ (a + H2)
then consider g being Element of G such that
A1: x = a + g and
A2: g in H1 /\ H2 by Th103;
g in H2 by A2, Th82;
then A3: x in a + H2 by A1, Th103;
g in H1 by A2, Th82;
then x in a + H1 by A1, Th103;
hence x in (a + H1) /\ (a + H2) by A3; :: thesis: verum
end;
let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in (a + H1) /\ (a + H2) or x in a + (H1 /\ H2) )
assume A4: x in (a + H1) /\ (a + H2) ; :: thesis: x in a + (H1 /\ H2)
then x in a + H1 by XBOOLE_0:def 4;
then consider g being Element of G such that
A5: x = a + g and
A6: g in H1 by Th103;
x in a + H2 by A4, XBOOLE_0:def 4;
then consider g1 being Element of G such that
A7: x = a + g1 and
A8: g1 in H2 by Th103;
g = g1 by A5, A7, Th6;
hence x in a + (H1 /\ H2) by A5, A6, A8, Th82, Th103; :: thesis: verum