let f1, f2 be PartFunc of REAL,REAL; :: thesis:
let x0 be Real; :: thesis:
assume that
A1: f1 is_left_differentiable_in x0 and
A2: f2 is_left_differentiable_in x0 ; :: thesis:
consider r1 being Real such that
A3: 0 < r1 and
A4: [.(x0 - r1),x0.] c= dom f1 by A1;
given r0 being Real such that A5: r0 > 0 and
A6: for g being Real st g in dom f2 & g in [.(x0 - r0),x0.] holds
f2 . g <> 0 ; :: thesis:
consider r2 being Real such that
A7: 0 < r2 and
A8: [.(x0 - r2),x0.] c= dom f2 by A2;
set r3 = min (r0,r2);
A9: 0 < min (r0,r2) by A5, A7, XXREAL_0:15;
then A10: x0 - (min (r0,r2)) <= x0 by XREAL_1:43;
min (r0,r2) <= r2 by XXREAL_0:17;
then A11: x0 - r2 <= x0 - (min (r0,r2)) by XREAL_1:13;
then x0 - r2 <= x0 by A10, XXREAL_0:2;
then A12: x0 in [.(x0 - r2),x0.] by XXREAL_1:1;
x0 - (min (r0,r2)) in { g where g is Real : ( x0 - r2 <= g & g <= x0 ) } by A10, A11;
then x0 - (min (r0,r2)) in [.(x0 - r2),x0.] by RCOMP_1:def 1;
then [.(x0 - (min (r0,r2))),x0.] c= [.(x0 - r2),x0.] by A12, XXREAL_2:def 12;
then A13: [.(x0 - (min (r0,r2))),x0.] c= dom f2 by A8;
min (r0,r2) <= r0 by XXREAL_0:17;
then A14: x0 - r0 <= x0 - (min (r0,r2)) by XREAL_1:13;
then x0 - r0 <= x0 by A10, XXREAL_0:2;
then A15: x0 in [.(x0 - r0),x0.] by XXREAL_1:1;
x0 - (min (r0,r2)) in { g where g is Real : ( x0 - r0 <= g & g <= x0 ) } by A10, A14;
then x0 - (min (r0,r2)) in [.(x0 - r0),x0.] by RCOMP_1:def 1;
then A16: [.(x0 - (min (r0,r2))),x0.] c= [.(x0 - r0),x0.] by A15, XXREAL_2:def 12;
set r = min (r1,(min (r0,r2)));
A17: 0 < min (r1,(min (r0,r2))) by A3, A9, XXREAL_0:15;
then A18: x0 - (min (r1,(min (r0,r2)))) <= x0 by XREAL_1:43;
min (r1,(min (r0,r2))) <= min (r0,r2) by XXREAL_0:17;
then A19: x0 - (min (r0,r2)) <= x0 - (min (r1,(min (r0,r2)))) by XREAL_1:13;
then x0 - (min (r0,r2)) <= x0 by A18, XXREAL_0:2;
then A20: x0 in [.(x0 - (min (r0,r2))),x0.] by XXREAL_1:1;
x0 - (min (r1,(min (r0,r2)))) in { g where g is Real : ( x0 - (min (r0,r2)) <= g & g <= x0 ) } by A18, A19;
then x0 - (min (r1,(min (r0,r2)))) in [.(x0 - (min (r0,r2))),x0.] by RCOMP_1:def 1;
then A21: [.(x0 - (min (r1,(min (r0,r2))))),x0.] c= [.(x0 - (min (r0,r2))),x0.] by A20, XXREAL_2:def 12;
[.(x0 - (min (r1,(min (r0,r2))))),x0.] c= dom (f2 ^)

assume not [.(x0 - (min (r1,(min (r0,r2))))),x0.] c= dom (f2 ^) ; :: thesis:
then consider x being object such that
A22: x in [.(x0 - (min (r1,(min (r0,r2))))),x0.] and
A23: not x in dom (f2 ^) ;
reconsider x = x as Real by A22;
A24: x in [.(x0 - (min (r0,r2))),x0.] by A21, A22;
A25: not x in (dom f2) \ (f2 " {0}) by A23, RFUNCT_1:def 2;

per cases by A25, XBOOLE_0:def 5;

suppose not x in dom f2 ; :: thesis:

hence contradiction by A13, A24; :: thesis:

end;

suppose A26: x in f2 " {0} ; :: thesis:

then f2 . x in {0} by FUNCT_1:def 7;
then A27: f2 . x = 0 by TARSKI:def 1;
x in dom f2 by A26, FUNCT_1:def 7;
hence contradiction by A6, A16, A24, A27; :: thesis:

end;

hence contradiction ; :: thesis:

end;

then A28: [.(x0 - (min (r1,(min (r0,r2))))),x0.] c= (dom f2) \ (f2 " {0}) by RFUNCT_1:def 2;
min (r1,(min (r0,r2))) <= r1 by XXREAL_0:17;
then A29: x0 - r1 <= x0 - (min (r1,(min (r0,r2)))) by XREAL_1:13;
then x0 - r1 <= x0 by A18, XXREAL_0:2;
then A30: x0 in [.(x0 - r1),x0.] by XXREAL_1:1;
x0 - (min (r1,(min (r0,r2)))) in { g where g is Real : ( x0 - r1 <= g & g <= x0 ) } by A18, A29;
then x0 - (min (r1,(min (r0,r2)))) in [.(x0 - r1),x0.] by RCOMP_1:def 1;
then [.(x0 - (min (r1,(min (r0,r2))))),x0.] c= [.(x0 - r1),x0.] by A30, XXREAL_2:def 12;
then A31: [.(x0 - (min (r1,(min (r0,r2))))),x0.] c= dom f1 by A4;
A32: for h being non-zero 0 -convergent Real_Sequence
for c being constant Real_Sequence st rng c = {x0} & rng (h + c) c= dom (f1 / f2) & ( for n being Nat holds h . n < 0 ) holds
( (h ") (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) is convergent & lim ((h ") (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c))) = (((Ldiff (f1,x0)) * (f2 . x0)) - ((Ldiff (f2,x0)) * (f1 . x0))) / ((f2 . x0) ^2) )

proof

let h be non-zero 0 -convergent Real_Sequence; :: thesis:
let c be constant Real_Sequence; :: thesis:
assume that
A33: rng c = {x0} and
A34: rng (h + c) c= dom (f1 / f2) and
A35: for n being Nat holds h . n < 0 ; :: thesis:
A36: rng (h + c) c= (dom f1) /\ ((dom f2) \ (f2 " {0})) by A34, RFUNCT_1:def 1;
0 <= min (r1,(min (r0,r2))) by A3, A9, XXREAL_0:15;
then x0 - (min (r1,(min (r0,r2)))) <= x0 by XREAL_1:43;
then A37: x0 in [.(x0 - (min (r1,(min (r0,r2))))),x0.] by XXREAL_1:1;
then A38: x0 in dom f1 by A31;
A39: rng c c= dom f1 by A33, A38, TARSKI:def 1;
(dom f1) /\ ((dom f2) \ (f2 " {0})) c= dom f1 by XBOOLE_1:17;
then A40: rng (h + c) c= dom f1 by A36;
then A41: lim ((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) = Ldiff (f1,x0) by A1, A33, A35, Th9;
A42: x0 in (dom f2) \ (f2 " {0}) by A28, A37;
rng c c= (dom f2) \ (f2 " {0}) by A33, A42, TARSKI:def 1;
then A43: rng c c= dom (f2 ^) by RFUNCT_1:def 2;
then A44: rng c c= (dom f1) /\ (dom (f2 ^)) by A39, XBOOLE_1:19;
A45: (h ") (#) ((f1 /* (h + c)) - (f1 /* c)) is convergent by A1, A33, A35, A40;
A46: f2 /* c is non-zero by A43, RFUNCT_2:11;

A47: now :: thesis:

let n be Element of NAT ; :: thesis:
thus ((h ") (#) (((f1 /* (h + c)) (#) (f2 /* c)) - ((f1 /* c) (#) (f2 /* (h + c))))) . n = ((h ") . n) * ((((f1 /* (h + c)) (#) (f2 /* c)) - ((f1 /* c) (#) (f2 /* (h + c)))) . n) by SEQ_1:8
.= ((h ") . n) * ((((f1 /* (h + c)) (#) (f2 /* c)) . n) - (((f1 /* c) (#) (f2 /* (h + c))) . n)) by RFUNCT_2:1
.= ((h ") . n) * ((((f1 /* (h + c)) . n) * ((f2 /* c) . n)) - (((f1 /* c) (#) (f2 /* (h + c))) . n)) by SEQ_1:8
.= ((h ") . n) * ((((((f1 /* (h + c)) . n) - ((f1 /* c) . n)) * ((f2 /* c) . n)) + (((f1 /* c) . n) * ((f2 /* c) . n))) - (((f1 /* c) . n) * ((f2 /* (h + c)) . n))) by SEQ_1:8
.= ((((h ") . n) * (((f1 /* (h + c)) . n) - ((f1 /* c) . n))) * ((f2 /* c) . n)) - (((f1 /* c) . n) * (((h ") . n) * (((f2 /* (h + c)) . n) - ((f2 /* c) . n))))
.= ((((h ") . n) * (((f1 /* (h + c)) - (f1 /* c)) . n)) * ((f2 /* c) . n)) - (((f1 /* c) . n) * (((h ") . n) * (((f2 /* (h + c)) . n) - ((f2 /* c) . n)))) by RFUNCT_2:1
.= ((((h ") . n) * (((f1 /* (h + c)) - (f1 /* c)) . n)) * ((f2 /* c) . n)) - (((f1 /* c) . n) * (((h ") . n) * (((f2 /* (h + c)) - (f2 /* c)) . n))) by RFUNCT_2:1
.= ((((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) . n) * ((f2 /* c) . n)) - (((f1 /* c) . n) * (((h ") . n) * (((f2 /* (h + c)) - (f2 /* c)) . n))) by SEQ_1:8
.= ((((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) . n) * ((f2 /* c) . n)) - (((f1 /* c) . n) * (((h ") (#) ((f2 /* (h + c)) - (f2 /* c))) . n)) by SEQ_1:8
.= ((((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) . n) - (((f1 /* c) . n) * (((h ") (#) ((f2 /* (h + c)) - (f2 /* c))) . n)) by SEQ_1:8
.= ((((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) . n) - (((f1 /* c) (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c)))) . n) by SEQ_1:8
.= ((((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) - ((f1 /* c) (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c))))) . n by RFUNCT_2:1 ; :: thesis:

end;

now :: thesis:

let n be Element of NAT ; :: thesis:
thus ((f2 /* c) + ((f2 /* (h + c)) - (f2 /* c))) . n = ((f2 /* c) . n) + (((f2 /* (h + c)) - (f2 /* c)) . n) by SEQ_1:7
.= ((f2 /* c) . n) + (((f2 /* (h + c)) . n) - ((f2 /* c) . n)) by RFUNCT_2:1
.= (f2 /* (h + c)) . n ; :: thesis:

end;

then A48: (f2 /* c) + ((f2 /* (h + c)) - (f2 /* c)) = f2 /* (h + c) by FUNCT_2:63;
(dom f1) /\ ((dom f2) \ (f2 " {0})) c= (dom f2) \ (f2 " {0}) by XBOOLE_1:17;
then A49: rng (h + c) c= (dom f2) \ (f2 " {0}) by A36;
then A50: rng (h + c) c= dom (f2 ^) by RFUNCT_1:def 2;
then A51: rng (h + c) c= (dom f1) /\ (dom (f2 ^)) by A40, XBOOLE_1:19;
A52: f2 /* (h + c) is non-zero by A50, RFUNCT_2:11;
then A53: (f2 /* (h + c)) (#) (f2 /* c) is non-zero by A46, SEQ_1:35;
(h ") (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) = (h ") (#) (((f1 (#) (f2 ^)) /* (h + c)) - ((f1 / f2) /* c)) by RFUNCT_1:31
.= (h ") (#) (((f1 (#) (f2 ^)) /* (h + c)) - ((f1 (#) (f2 ^)) /* c)) by RFUNCT_1:31
.= (h ") (#) (((f1 /* (h + c)) (#) ((f2 ^) /* (h + c))) - ((f1 (#) (f2 ^)) /* c)) by A51, RFUNCT_2:8
.= (h ") (#) (((f1 /* (h + c)) /" (f2 /* (h + c))) - ((f1 (#) (f2 ^)) /* c)) by A50, RFUNCT_2:12
.= (h ") (#) (((f1 /* (h + c)) /" (f2 /* (h + c))) - ((f1 /* c) (#) ((f2 ^) /* c))) by A44, RFUNCT_2:8
.= (h ") (#) (((f1 /* (h + c)) /" (f2 /* (h + c))) - ((f1 /* c) /" (f2 /* c))) by A43, RFUNCT_2:12
.= (h ") (#) ((((f1 /* (h + c)) (#) (f2 /* c)) - ((f1 /* c) (#) (f2 /* (h + c)))) /" ((f2 /* (h + c)) (#) (f2 /* c))) by A52, A46, SEQ_1:50
.= ((h ") (#) (((f1 /* (h + c)) (#) (f2 /* c)) - ((f1 /* c) (#) (f2 /* (h + c))))) /" ((f2 /* (h + c)) (#) (f2 /* c)) by SEQ_1:41 ;
then A54: (h ") (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) = ((((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) - ((f1 /* c) (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c))))) /" ((f2 /* (h + c)) (#) (f2 /* c)) by A47, FUNCT_2:63;
(dom f2) \ (f2 " {0}) c= dom f2 by XBOOLE_1:36;
then A55: rng (h + c) c= dom f2 by A49;
then A56: lim ((h ") (#) ((f2 /* (h + c)) - (f2 /* c))) = Ldiff (f2,x0) by A2, A33, A35, Th9;
A57: (h ") (#) ((f2 /* (h + c)) - (f2 /* c)) is convergent by A2, A33, A35, A55;

now :: thesis:

let n be Element of NAT ; :: thesis:
A58: h . n <> 0 by A35;
thus (h (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c)))) . n = ((h (#) (h ")) (#) ((f2 /* (h + c)) - (f2 /* c))) . n by SEQ_1:14
.= ((h (#) (h ")) . n) * (((f2 /* (h + c)) - (f2 /* c)) . n) by SEQ_1:8
.= ((h . n) * ((h ") . n)) * (((f2 /* (h + c)) - (f2 /* c)) . n) by SEQ_1:8
.= ((h . n) * ((h . n) ")) * (((f2 /* (h + c)) - (f2 /* c)) . n) by VALUED_1:10
.= 1 * (((f2 /* (h + c)) - (f2 /* c)) . n) by A58, XCMPLX_0:def 7
.= ((f2 /* (h + c)) - (f2 /* c)) . n ; :: thesis:

end;

then A59: h (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c))) = (f2 /* (h + c)) - (f2 /* c) by FUNCT_2:63;
A60: for m being Element of NAT holds c . m = x0

proof

let m be Element of NAT ; :: thesis:
c . m in rng c by VALUED_0:28;
hence c . m = x0 by A33, TARSKI:def 1; :: thesis:

end;

A61: for g being Real st 0 < g holds
ex n being Nat st
for m being Nat st n <= m holds
|.(((f1 /* c) . m) - (f1 . x0)).| < g

proof

let g be Real; :: thesis:
assume A62: 0 < g ; :: thesis:
take n = 0 ; :: thesis:
let m be Nat; :: thesis:
assume n <= m ; :: thesis:
A63: m in NAT by ORDINAL1:def 12;
|.(((f1 /* c) . m) - (f1 . x0)).| = |.((f1 . (c . m)) - (f1 . x0)).| by A39, FUNCT_2:108, A63
.= |.((f1 . x0) - (f1 . x0)).| by A60, A63
.= 0 by ABSVALUE:def 1 ;
hence |.(((f1 /* c) . m) - (f1 . x0)).| < g by A62; :: thesis:

end;

then A64: f1 /* c is convergent by SEQ_2:def 6;
then A65: lim (f1 /* c) = f1 . x0 by A61, SEQ_2:def 7;
dom (f2 ^) = (dom f2) \ (f2 " {0}) by RFUNCT_1:def 2;
then A66: dom (f2 ^) c= dom f2 by XBOOLE_1:36;
A67: for g being Real st 0 < g holds
ex n being Nat st
for m being Nat st n <= m holds
|.(((f2 /* c) . m) - (f2 . x0)).| < g

proof

let g be Real; :: thesis:
assume A68: 0 < g ; :: thesis:
take n = 0 ; :: thesis:
let m be Nat; :: thesis:
assume n <= m ; :: thesis:
A69: m in NAT by ORDINAL1:def 12;
|.(((f2 /* c) . m) - (f2 . x0)).| = |.((f2 . (c . m)) - (f2 . x0)).| by A43, A66, FUNCT_2:108, XBOOLE_1:1, A69
.= |.((f2 . x0) - (f2 . x0)).| by A60, A69
.= 0 by ABSVALUE:def 1 ;
hence |.(((f2 /* c) . m) - (f2 . x0)).| < g by A68; :: thesis:

end;

then A70: f2 /* c is convergent by SEQ_2:def 6;
then A71: lim (f2 /* c) = f2 . x0 by A67, SEQ_2:def 7;
h (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c))) is convergent by A57;
then A72: f2 /* (h + c) is convergent by A70, A59, A48;
then A73: (f2 /* (h + c)) (#) (f2 /* c) is convergent by A70;
(h ") (#) ((f2 /* (h + c)) - (f2 /* c)) is convergent by A2, A33, A35, A55;
then lim (h (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c)))) = (lim h) * (lim ((h ") (#) ((f2 /* (h + c)) - (f2 /* c)))) by SEQ_2:15
.= 0 ;
then 0 = (lim (f2 /* (h + c))) - (f2 . x0) by A70, A71, A59, A72, SEQ_2:12;
then A74: lim ((f2 /* (h + c)) (#) (f2 /* c)) = (f2 . x0) ^2 by A70, A71, A72, SEQ_2:15;
A75: lim ((f2 /* (h + c)) (#) (f2 /* c)) <> 0

proof

assume not lim ((f2 /* (h + c)) (#) (f2 /* c)) <> 0 ; :: thesis:
then f2 . x0 = 0 by A74, XCMPLX_1:6;
hence contradiction by A6, A8, A15, A12; :: thesis:

end;

(h ") (#) ((f1 /* (h + c)) - (f1 /* c)) is convergent by A1, A33, A35, A40;
then A76: ((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c) is convergent by A70;
A77: (f1 /* c) (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c))) is convergent by A57, A64;
then A78: (((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) - ((f1 /* c) (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c)))) is convergent by A76;
then lim ((h ") (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c))) = (lim ((((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) - ((f1 /* c) (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c)))))) / (lim ((f2 /* (h + c)) (#) (f2 /* c))) by A53, A73, A75, A54, SEQ_2:24
.= ((lim (((h ") (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c))) - (lim ((f1 /* c) (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c)))))) / (lim ((f2 /* (h + c)) (#) (f2 /* c))) by A77, A76, SEQ_2:12
.= (((lim ((h ") (#) ((f1 /* (h + c)) - (f1 /* c)))) * (lim (f2 /* c))) - (lim ((f1 /* c) (#) ((h ") (#) ((f2 /* (h + c)) - (f2 /* c)))))) / (lim ((f2 /* (h + c)) (#) (f2 /* c))) by A45, A70, SEQ_2:15
.= (((Ldiff (f1,x0)) * (f2 . x0)) - ((Ldiff (f2,x0)) * (f1 . x0))) / ((f2 . x0) ^2) by A41, A57, A56, A64, A65, A71, A74, SEQ_2:15 ;
hence ( (h ") (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) is convergent & lim ((h ") (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c))) = (((Ldiff (f1,x0)) * (f2 . x0)) - ((Ldiff (f2,x0)) * (f1 . x0))) / ((f2 . x0) ^2) ) by A53, A73, A75, A78, A54, SEQ_2:23; :: thesis:

end;

[.(x0 - (min (r1,(min (r0,r2))))),x0.] c= (dom f1) /\ ((dom f2) \ (f2 " {0})) by A31, A28, XBOOLE_1:19;
then [.(x0 - (min (r1,(min (r0,r2))))),x0.] c= dom (f1 / f2) by RFUNCT_1:def 1;
hence ( f1 / f2 is_left_differentiable_in x0 & Ldiff ((f1 / f2),x0) = (((Ldiff (f1,x0)) * (f2 . x0)) - ((Ldiff (f2,x0)) * (f1 . x0))) / ((f2 . x0) ^2) ) by A17, A32, Th9; :: thesis: