let x, y be Point of Complex_linfty_Space; :: thesis: for c being Complex holds
( ( ||.x.|| = 0 implies x = 0. Complex_linfty_Space ) & ( x = 0. Complex_linfty_Space implies ||.x.|| = 0 ) & 0 <= ||.x.|| & ||.(x + y).|| <= ||.x.|| + ||.y.|| & ||.(c * x).|| = |.c.| * ||.x.|| )
let c be Complex; :: thesis: ( ( ||.x.|| = 0 implies x = 0. Complex_linfty_Space ) & ( x = 0. Complex_linfty_Space implies ||.x.|| = 0 ) & 0 <= ||.x.|| & ||.(x + y).|| <= ||.x.|| + ||.y.|| & ||.(c * x).|| = |.c.| * ||.x.|| )
A1: for n being Nat holds |.(c (#) (seq_id x)).| . n = |.c.| * (|.(seq_id x).| . n)
proof
let n be Nat; :: thesis: |.(c (#) (seq_id x)).| . n = |.c.| * (|.(seq_id x).| . n)
|.(c (#) (seq_id x)).| . n = |.((c (#) (seq_id x)) . n).| by VALUED_1:18
.= |.(c * ((seq_id x) . n)).| by VALUED_1:6
.= |.c.| * |.((seq_id x) . n).| by COMPLEX1:65
.= |.c.| * (|.(seq_id x).| . n) by VALUED_1:18 ;
hence |.(c (#) (seq_id x)).| . n = |.c.| * (|.(seq_id x).| . n) ; :: thesis: verum
end;
|.(seq_id x).| . 1 = |.((seq_id x) . 1).| by VALUED_1:18;
then A2: 0 <= |.(seq_id x).| . 1 by COMPLEX1:46;
A3: for n being Nat holds |.(seq_id (x + y)).| . n = |.(((seq_id x) . n) + ((seq_id y) . n)).|
proof
let n be Nat; :: thesis: |.(seq_id (x + y)).| . n = |.(((seq_id x) . n) + ((seq_id y) . n)).|
A4: n in NAT by ORDINAL1:def 12;
|.(seq_id (x + y)).| . n = |.(seq_id ((seq_id x) + (seq_id y))).| . n by Th2
.= |.(((seq_id x) + (seq_id y)) . n).| by VALUED_1:18
.= |.(((seq_id x) . n) + ((seq_id y) . n)).| by VALUED_1:1, A4 ;
hence |.(seq_id (x + y)).| . n = |.(((seq_id x) . n) + ((seq_id y) . n)).| ; :: thesis: verum
end;
A5: for n being Nat holds |.(seq_id (x + y)).| . n <= (|.(seq_id x).| . n) + (|.(seq_id y).| . n)
proof
let n be Nat; :: thesis: |.(seq_id (x + y)).| . n <= (|.(seq_id x).| . n) + (|.(seq_id y).| . n)
|.(((seq_id x) . n) + ((seq_id y) . n)).| <= |.((seq_id x) . n).| + |.((seq_id y) . n).| by COMPLEX1:56;
then |.(seq_id (x + y)).| . n <= |.((seq_id x) . n).| + |.((seq_id y) . n).| by A3;
then |.(seq_id (x + y)).| . n <= (|.(seq_id x).| . n) + |.((seq_id y) . n).| by VALUED_1:18;
hence |.(seq_id (x + y)).| . n <= (|.(seq_id x).| . n) + (|.(seq_id y).| . n) by VALUED_1:18; :: thesis: verum
end;
A6: for n being Nat holds |.(seq_id (x + y)).| . n <= (|.(seq_id x).| + |.(seq_id y).|) . n
proof
let n be Nat; :: thesis: |.(seq_id (x + y)).| . n <= (|.(seq_id x).| + |.(seq_id y).|) . n
(|.(seq_id x).| . n) + (|.(seq_id y).| . n) = (|.(seq_id x).| + |.(seq_id y).|) . n by SEQ_1:7;
hence |.(seq_id (x + y)).| . n <= (|.(seq_id x).| + |.(seq_id y).|) . n by A5; :: thesis: verum
end;
A7: now :: thesis: ( ||.x.|| = 0 implies x = 0. Complex_linfty_Space )
A8: x in the_set_of_ComplexSequences by Def1;
assume A9: ||.x.|| = 0 ; :: thesis: x = 0. Complex_linfty_Space
( ||.x.|| = upper_bound (rng |.(seq_id x).|) & seq_id x is bounded ) by Th2;
then for n being Nat holds 0c = (seq_id x) . n by A9, Lm10;
hence x = 0. Complex_linfty_Space by A8, Th2, CSSPACE:5; :: thesis: verum
end;
seq_id x is bounded by Def1;
then |.(seq_id x).| is bounded by Lm8;
then A10: 0 <= upper_bound (rng |.(seq_id x).|) by A2, Lm2;
seq_id y is bounded by Def1;
then A11: |.(seq_id y).| is bounded by Lm8;
seq_id x is bounded by Def1;
then |.(seq_id x).| is bounded by Lm8;
then rng |.(seq_id x).| is real-bounded by MEASURE6:39;
then A12: rng |.(seq_id x).| is bounded_above ;
A13: now :: thesis: ( x = 0. Complex_linfty_Space implies ||.x.|| = 0 )
assume x = 0. Complex_linfty_Space ; :: thesis: ||.x.|| = 0
then A14: for n being Nat holds (seq_id x) . n = 0c by Th2;
thus ||.x.|| = upper_bound (rng |.(seq_id x).|) by Th2
.= 0 by A14, Lm7 ; :: thesis: verum
end;
seq_id x is bounded by Def1;
then A15: |.(seq_id x).| is bounded by Lm8;
now :: thesis: for n being Nat holds |.(seq_id (x + y)).| . n <= (upper_bound (rng |.(seq_id x).|)) + (upper_bound (rng |.(seq_id y).|))
let n be Nat; :: thesis: |.(seq_id (x + y)).| . n <= (upper_bound (rng |.(seq_id x).|)) + (upper_bound (rng |.(seq_id y).|))
A16: |.(seq_id y).| . n <= upper_bound (rng |.(seq_id y).|) by A11, Lm2;
( (|.(seq_id x).| + |.(seq_id y).|) . n = (|.(seq_id x).| . n) + (|.(seq_id y).| . n) & |.(seq_id x).| . n <= upper_bound (rng |.(seq_id x).|) ) by A15, Lm2, SEQ_1:7;
then A17: (|.(seq_id x).| + |.(seq_id y).|) . n <= (upper_bound (rng |.(seq_id x).|)) + (upper_bound (rng |.(seq_id y).|)) by A16, XREAL_1:7;
|.(seq_id (x + y)).| . n <= (|.(seq_id x).| + |.(seq_id y).|) . n by A6;
hence |.(seq_id (x + y)).| . n <= (upper_bound (rng |.(seq_id x).|)) + (upper_bound (rng |.(seq_id y).|)) by A17, XXREAL_0:2; :: thesis: verum
end;
then A18: upper_bound (rng |.(seq_id (x + y)).|) <= (upper_bound (rng |.(seq_id x).|)) + (upper_bound (rng |.(seq_id y).|)) by Lm1;
A19: ( ||.y.|| = upper_bound (rng |.(seq_id y).|) & upper_bound (rng |.(seq_id (x + y)).|) = ||.(x + y).|| ) by Th2;
||.(c * x).|| = upper_bound (rng |.(seq_id (c * x)).|) by Th2
.= upper_bound (rng |.(seq_id (c (#) (seq_id x))).|) by Th2
.= upper_bound (rng (|.c.| (#) |.(seq_id x).|)) by A1, SEQ_1:9
.= upper_bound (|.c.| ** (rng |.(seq_id x).|)) by INTEGRA2:17
.= |.c.| * (upper_bound (rng |.(seq_id x).|)) by A12, COMPLEX1:46, INTEGRA2:13
.= |.c.| * ||.x.|| by Th2 ;
hence ( ( ||.x.|| = 0 implies x = 0. Complex_linfty_Space ) & ( x = 0. Complex_linfty_Space implies ||.x.|| = 0 ) & 0 <= ||.x.|| & ||.(x + y).|| <= ||.x.|| + ||.y.|| & ||.(c * x).|| = |.c.| * ||.x.|| ) by A7, A13, A10, A19, A18, Th2; :: thesis: verum