let X be Complex_Banach_Algebra; :: thesis: for n being Nat
for z, w being Element of X st z,w are_commutative holds
(Partial_Sums ((z + w) ExpSeq)) . n = (Partial_Sums (Alfa (n,z,w))) . n
let n be Nat; :: thesis: for z, w being Element of X st z,w are_commutative holds
(Partial_Sums ((z + w) ExpSeq)) . n = (Partial_Sums (Alfa (n,z,w))) . n
let z, w be Element of X; :: thesis: ( z,w are_commutative implies (Partial_Sums ((z + w) ExpSeq)) . n = (Partial_Sums (Alfa (n,z,w))) . n )
assume A1: z,w are_commutative ; :: thesis: (Partial_Sums ((z + w) ExpSeq)) . n = (Partial_Sums (Alfa (n,z,w))) . n
defpred S1[ Nat] means (Partial_Sums ((z + w) ExpSeq)) . $1 = (Partial_Sums (Alfa ($1,z,w))) . $1;
A2: for k being Nat st S1[k] holds
S1[k + 1]
proof
let k be Nat; :: thesis: ( S1[k] implies S1[k + 1] )
assume A3: (Partial_Sums ((z + w) ExpSeq)) . k = (Partial_Sums (Alfa (k,z,w))) . k ; :: thesis: S1[k + 1]
(k + 1) -' (k + 1) = 0 by XREAL_1:232;
then (Alfa ((k + 1),z,w)) . (k + 1) = ((z ExpSeq) . (k + 1)) * ((Partial_Sums (w ExpSeq)) . 0) by Def4
.= ((z ExpSeq) . (k + 1)) * ((w ExpSeq) . 0) by BHSP_4:def 1
.= ((z ExpSeq) . (k + 1)) * (1. X) by Th20
.= (z ExpSeq) . (k + 1) by VECTSP_1:def 4
.= (Expan_e ((k + 1),z,w)) . (k + 1) by Th23 ;
then A4: ((Partial_Sums (Expan_e ((k + 1),z,w))) . k) + ((Alfa ((k + 1),z,w)) . (k + 1)) = (Partial_Sums (Expan_e ((k + 1),z,w))) . (k + 1) by BHSP_4:def 1
.= (1r / ((k + 1) !)) * ((z + w) #N (k + 1)) by A1, Th18 ;
(Partial_Sums (Alfa ((k + 1),z,w))) . (k + 1) = ((Partial_Sums (Alfa ((k + 1),z,w))) . k) + ((Alfa ((k + 1),z,w)) . (k + 1)) by BHSP_4:def 1
.= (((Partial_Sums (Alfa (k,z,w))) . k) + ((Partial_Sums (Expan_e ((k + 1),z,w))) . k)) + ((Alfa ((k + 1),z,w)) . (k + 1)) by Th22
.= ((Partial_Sums ((z + w) ExpSeq)) . k) + (((Partial_Sums (Expan_e ((k + 1),z,w))) . k) + ((Alfa ((k + 1),z,w)) . (k + 1))) by A3, RLVECT_1:def 3 ;
then (Partial_Sums (Alfa ((k + 1),z,w))) . (k + 1) = ((Partial_Sums ((z + w) ExpSeq)) . k) + (((z + w) ExpSeq) . (k + 1)) by A4, Def1
.= (Partial_Sums ((z + w) ExpSeq)) . (k + 1) by BHSP_4:def 1 ;
hence (Partial_Sums ((z + w) ExpSeq)) . (k + 1) = (Partial_Sums (Alfa ((k + 1),z,w))) . (k + 1) ; :: thesis: verum
end;
A5: (Partial_Sums ((z + w) ExpSeq)) . 0 = ((z + w) ExpSeq) . 0 by BHSP_4:def 1
.= 1. X by Th20 ;
A6: 0 -' 0 = 0 by XREAL_1:232;
(Partial_Sums (Alfa (0,z,w))) . 0 = (Alfa (0,z,w)) . 0 by BHSP_4:def 1
.= ((z ExpSeq) . 0) * ((Partial_Sums (w ExpSeq)) . 0) by A6, Def4
.= ((z ExpSeq) . 0) * ((w ExpSeq) . 0) by BHSP_4:def 1
.= (1. X) * ((w ExpSeq) . 0) by Th20
.= (1. X) * (1. X) by Th20
.= 1. X by VECTSP_1:def 4 ;
then A7: S1[ 0 ] by A5;
for n being Nat holds S1[n] from NAT_1:sch 2(A7, A2);
 hence (Partial_Sums ((z + w) ExpSeq)) . n = (Partial_Sums (Alfa (n,z,w))) . n ; :: thesis: verum